meson.build

# SPDX-FileCopyrightText: 2016-2020 Bruce Cowan <bruce@bcowan.me.uk>
#
# SPDX-License-Identifier: CC0-1.0

project('rugby', 'c',
    version: '0.2.0',
    license:'GPL',
    default_options: ['c_std=gnu11', 'warning_level=3'])

datadir = get_option('datadir')

gnome = import('gnome')

gio_dep = dependency('gio-2.0', version: '>= 2.44')
gtk_dep = dependency('gtk+-3.0', version: '>= 3.16')

conf = configuration_data()

git = find_program('git', required: false)
if git.found()
    VERSION = run_command('git', 'describe', '--always').stdout().strip()
else
    VERSION = meson.version()
endif

conf.set_quoted('VERSION', VERSION)

cflags = []
cflags += ['-DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_44',
           '-DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_44']
cflags += ['-DGDK_VERSION_MIN_REQUIRED=GDK_VERSION_3_16',
           '-DGDK_VERSION_MAX_ALLOWED=GDK_VERSION_3_16']
cflags += '-Wno-overlength-strings'

cc = meson.get_compiler('c')

add_project_arguments(cc.get_supported_arguments(cflags),
                      language: 'c')

subdir('data')
subdir('src')

meson.add_install_script('build-aux/post_install.py')