meson.build

# SPDX-FileCopyrightText: 2016-2022 Bruce Cowan <bruce@bcowan.me.uk>
#
# SPDX-License-Identifier: GPL-3.0-or-later

project('rugby', 'c',
  version: '0.4.alpha',
  license:'GPLv3+',
  meson_version: '>= 0.57.0',
  default_options: [
    'buildtype=debugoptimized',
    'c_std=gnu11',
    'warning_level=3'
  ],
)

datadir = get_option('datadir')
desktopdir = datadir / 'applications'

gnome = import('gnome')

gio_dep = dependency('gio-2.0', version: '>= 2.66')
gtk_dep = dependency('gtk4', version: '>= 4.0')
libadwaita_dep = dependency('libadwaita-1')

conf = configuration_data()
conf.set_quoted('VERSION','@VCS_TAG@')

devel = get_option('development')
conf.set10('DEVELOPMENT', devel)

if devel
  conf.set_quoted('VERSION', '@0@-@VCS_TAG@'.format(meson.project_version()))
else
  conf.set_quoted('VERSION', meson.project_version())
endif

config_h = vcs_tag(
  input: configure_file(
    output: 'config.h.in',
    configuration: conf
  ),
  output: 'config.h',
  command: ['git', 'rev-parse', '--short', 'HEAD'],
  fallback: devel ? 'devel' : '',
)

cflags = ['-DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_66',
          '-DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_66',
          '-DGDK_VERSION_MIN_REQUIRED=GDK_VERSION_4_0',
          '-DGDK_VERSION_MAX_ALLOWED=GDK_VERSION_4_0',
          '-Wno-overlength-strings',
]

cc = meson.get_compiler('c')

add_project_arguments(cc.get_supported_arguments(cflags),
                      language: 'c')

subdir('data')
subdir('src')

gnome.post_install(glib_compile_schemas: true)