meson.build

# SPDX-FileCopyrightText: 2016-2022 Bruce Cowan <bruce@bcowan.me.uk>
#
# SPDX-License-Identifier: GPL-3.0-or-later

blueprints = custom_target('blueprints',
  input: files(
    'prefs.blp',
    'window.blp'
  ),
  output: '.',
  command: [find_program('blueprint-compiler'), 'batch-compile', '@OUTPUT@', '@CURRENT_SOURCE_DIR@', '@INPUT@'],
)

resources = gnome.compile_resources('gen-resources',
                                    'rugby.gresource.xml',
                                    source_dir: 'data',
                                    dependencies: blueprints)

desktop_file = 'uk.me.bcowan.Rugby.desktop'
install_data(desktop_file,
    install_dir: join_paths(get_option('datadir'), 'applications'))

desktop_utils = find_program('desktop-file-validate', required: false)
if desktop_utils.found()
    test('Validate desktop file', desktop_utils,
        args: [desktop_file])
endif

compiled_schemas = gnome.compile_schemas(
  build_by_default: true,
  depend_files: 'uk.me.bcowan.Rugby.gschema.xml',
)

install_data(
  'uk.me.bcowan.Rugby.gschema.xml',
  install_dir: datadir / 'glib-2.0' / 'schemas',
)