meson.build

# SPDX-FileCopyrightText: 2016-2020 Bruce Cowan <bruce@bcowan.me.uk>
# SPDX-License-Identifier: CC0-1.0

gnome = import('gnome')

conf = configuration_data()
conf.set('TRY_POINTS', get_option('try_points'))
conf.set('UTRY_POINTS', get_option('utry_points'))
conf.set('KICK_POINTS', get_option('kick_points'))

VCS_TAG = ''
COPYRIGHT_YEAR = '?'

git = find_program('git', required: false)
if git.found()
    VCS_TAG = run_command('git', 'describe', '--always').stdout().strip()
else
    VCS_TAG = 'unknown'
endif

conf.set_quoted('PACKAGE_VERSION', VCS_TAG)
conf.set_quoted('COPYRIGHT_YEAR', COPYRIGHT_YEAR)

config_h = configure_file(configuration: conf, output: 'config.h')

sources = files(
    'main.c',
    'rugby-app-window.c',
    'rugby-list-store.c',
    'rugby-possibility.c',
    'rugby-possibility-widget.c'
)

sources += config_h
sources += resources

deps = [gio_dep, gtk_dep]

executable('rugby',
           sources,
           dependencies: deps,
           install: true)