meson.build

# SPDX-FileCopyrightText: 2016-2023 Bruce Cowan <bruce@bcowan.me.uk>
#
# SPDX-License-Identifier: GPL-3.0-or-later

blueprints = custom_target('blueprints',
  input: files(
    'gtk/help-overlay.blp',
    'gtk/prefs.blp',
    'gtk/window.blp'
  ),
  output: '.',
  command: [find_program('blueprint-compiler'), 'batch-compile', '@OUTPUT@', '@CURRENT_SOURCE_DIR@', '@INPUT@'],
)

resources = gnome.compile_resources('gen-resources',
                                    'uk.me.bcowan.Rugby.gresource.xml',
                                    source_dir: 'data',
                                    dependencies: blueprints)

install_data('uk.me.bcowan.Rugby.desktop',
  install_dir: join_paths(get_option('datadir'), 'applications')
)

install_data(
  'uk.me.bcowan.Rugby.gschema.xml',
  install_dir: datadir / 'glib-2.0' / 'schemas',
)

install_data(
  'uk.me.bcowan.Rugby.metainfo.xml',
  install_dir: datadir / 'metainfo',
)

desktop_file_validate = find_program('desktop-file-validate', required: false)
if desktop_file_validate.found()
	test(
		'validate-desktop',
		desktop_file_validate,
		args: [
			'uk.me.bcowan.Rugby.desktop'
		]
	)
endif